बिना वर्ड के एक्सेल में मेल मर्ज (2 उपयुक्त तरीके)

मेल मर्ज करने के तरीके खोज रहे हैं एक्सेल में बिना शब्द . के ? तो यह आपके लिए सही जगह है। अगर माइक्रोसॉफ्ट वर्ड मेल मर्ज करने के कारण किसी कारण से उपलब्ध नहीं है पेचीदा होगा। हालांकि, यह असंभव नहीं है, क्योंकि शब्द मेल मर्ज करने के लिए अनिवार्य नहीं है संचालन। इस लेख में, हम आपको 2 . दिखाएंगे VBA मैक्रोज़ मेल मर्ज करने के लिए एक्सेल . में बिना शब्द . के ।

मेल मर्ज

जब कोई व्यक्ति या कोई कंपनी थोड़े से संशोधन (जैसे नाम, प्राप्तकर्ता का ईमेल पता, या प्राप्तकर्ता का पता) के साथ बड़ी संख्या में ईमेल भेजना चाहती है। फिर, संबंधित पार्टी जरूरतों को पूरा करने के लिए एक टेम्पलेट और संपादन योग्य फ़ील्ड बना सकती है। हम इस प्रकार के टेम्पलेट को मेल मर्ज . के रूप में जानते हैं ।

यह कुल समय बचाने वाला है। यह कार्य शब्द . के माध्यम से करना आम बात है प्रोसेसर (जैसे माइक्रोसॉफ्ट वर्ड , Google डॉक्स, आदि।)। वर्डस्टार पहली बार इस सुविधा को 80 के दशक के प्रारंभ में पेश किया था . उसके बाद, अन्य लोगों ने इस सुपर उपयोगी विशेषता को अपनाया है।

आम तौर पर, किसी को 5 . का अनुसरण करने की आवश्यकता होती है मेल मर्ज . के मुख्य चरण ऑपरेशन:

• सबसे पहले, मूल दस्तावेज़ ।
• दूसरा, डेटा स्रोत ।
• तीसरा, फ़ील्ड इनपुट करने के लिए।
• फिर, विलय मूल दस्तावेज़ . के साथ ।
• अंत में, सहेजें या भेजें ईमेल ।

बिना Word के Excel में मेल मर्ज करने के 2 आसान तरीके

जैसा माइक्रोसॉफ्ट वर्ड सबसे प्रमुख शब्द . है वहाँ प्रोसेसर, हम में से अधिकांश शब्द . को संबद्ध करते हैं जब हम टेक्स्ट सुनते हैं “मेल मर्ज " हालांकि, हम इसे अलग तरीके से करेंगे, केवल Microsoft Excel . का उपयोग करके मेल मर्ज करने के लिए . तो इसके बारे में और गहराई से जानने के लिए इस लेख को पढ़ें।

इसके अलावा, हम अपने मैक्रोज़ को प्रदर्शित करने के लिए दो डेटासेट का उपयोग करेंगे। , उनमें से पहले डेटासेट में निम्नलिखित कॉलम होते हैं:“नाम ”, “ईमेल पता ”, “शहर ”, और “सड़क पता " हम बाद वाले डेटासेट को इस लेख की दूसरी विधि में देखेंगे। इसके अतिरिक्त, गोपनीयता कारणों से, हमने 3 . बनाया है हमारे डेटासेट के लिए ईमेल पते और आखिरी वाला इस लेख लेखक का है, जिसका उपयोग हम यह सत्यापित करने के लिए करेंगे कि हम बिना किसी समस्या के ईमेल भेज सकते हैं।

पहली विधि के लिए, हमारी कार्यपत्रक नाम है “VBA1 " हम एक VBA . डालेंगे दो उप प्रक्रियाओं के साथ कोड एकल मॉड्यूल . का उपयोग करके मेल मर्ज करने के लिए एक्सेल . में बिना शब्द . के . फिर, हम इस कोड को चलाएंगे, जो हमारे पूर्वनिर्धारित टेम्पलेट का उपयोग करके सूचीबद्ध ग्राहकों को स्वचालित रूप से ईमेल भेज देगा। यह सब करने से पहले, आइए हम आपको दिखाते हैं कि मॉड्यूल . को कैसे लाया जाए विंडो और टाइप करें VBA कोड।

चरण:

• सबसे पहले, डेवलपर . की ओर से टैब>>> चुनें विजुअल बेसिक .
  • वैकल्पिक रूप से, आप ALT + F11 press दबा सकते हैं VBA . प्रदर्शित करने के लिए खिड़की ।

• दूसरा, सम्मिलित करें . से >>> चुनें मॉड्यूल ।

• तो, इससे मॉड्यूल सामने आएगा विंडो, जहां हम अपना VBA . टाइप करते हैं कोड।
• अगला, मॉड्यूल . के अंदर निम्न कोड टाइप करें खिड़की।

Option Explicit
Sub Mail_Merge_Only_Excel()
    Dim xSheet As Worksheet
    Dim mAddress As String, mSubject As String, eName As String, _
    eLocation As String, eCity As String
    Dim eRow As Long, x As Long
    Set xSheet = ThisWorkbook.Sheets("VBA1") 'WorkSheet Name
    With xSheet
        eRow = .Cells(.Rows.Count, 5).End(xlUp).Row
        For x = 5 To eRow 'Specific Row to Row to Last Row
                mAddress = .Cells(x, 3)
                mSubject = "Thank You for Your Loyalty"
                eName = .Cells(x, 2)
                eCity = .Cells(x, 4)
                eLocation = .Cells(x, 5)
                Call Mail_Merge_Only_Excel_Send_Mail(mAddress, mSubject, _
                eName, eLocation, eCity)
        Next x
    End With
End Sub
Sub Mail_Merge_Only_Excel_Send_Mail(mAddress As String, mSubject As String, _
eName As String, eLocation As String, eCity As String)
    Dim pApp As Object
    Dim pMail As Object
    Set pApp = CreateObject("Outlook.Application")
    Set pMail = pApp.CreateItem(0)
    With pMail
        .To = mAddress
        .CC = ""
        .BCC = ""
        .Subject = mSubject
        .Body = "Mr./Mrs. " & eName & vbNewLine & eCity & vbNewLine & eLocation & _
        vbNewLine & vbNewLine & "Hello! " _
        & "You are one of the most precious customers to us for the last quarter. " _
        & "As a token of appreciation, we are sending you 20$ coupon code for your " _
        & "next purchase at ExcelDemy. " _
        & "Use the coupon code 'ExcelDemy20' to avail of this discount." _
        & vbNewLine & "From," & vbNewLine & "ExcelDemy Team"
        .Send
    End With
    Set pMail = Nothing
    Set pApp = Nothing
End Sub

VBA कोड ब्रेकडाउन

• सबसे पहले, हम अपनी पहली उप प्रक्रिया को कॉल कर रहे हैं “Mail_Merge_Only_Excel "।
• दूसरा, हम चर प्रकारों की घोषणा कर रहे हैं और "VBA1" सेट कर रहे हैं ” हमारे कार्यपत्रक . के रूप में ।
• फिर, अंतिम पंक्ति संख्या पाई जाती है। इसके अलावा, हमारा मान पंक्ति 5 . से शुरू होता है , इसलिए हमने पंक्ति 5 . लगाई है हमारे कोड की अंतिम पंक्ति तक।
• फिर, हमारी दूसरी उप प्रक्रिया को कॉल करें “Mail_Merge_Only_Excel_Send_Mail "।
• उसके बाद, हम आउटलुक . का चयन कर रहे हैं हमारे मेल एप्लिकेशन . के रूप में ।
• फिर, ईमेल सामग्री हमारे कोड में सेट हो जाती है। इसके अतिरिक्त, हम vbNewLine . का उपयोग करते हैं ईमेल के मुख्य भाग में रिक्त पंक्तियाँ डालने के लिए।
• उसके बाद, “.भेजें ” का प्रयोग यहाँ हमारे ईमेल भेजने के लिए किया जाता है। इसलिए, हमें भेजें . दबाने की जरूरत नहीं है मैन्युअल रूप से ईमेल भेजने के लिए। इसके अलावा, हम “.डिस्प्ले . का उपयोग कर सकते हैं ईमेल को बिना भेजे प्रदर्शित करने के लिए।

• बाद में, सहेजें मॉड्यूल ।
• फिर, कर्सर को पहले उप प्रक्रिया के अंदर रखें और चलाएं . दबाएं ।
• अब, यदि आपने अपने आउटलुक पर लॉग ऑन नहीं किया है मेल ऐप, फिर आपको अपना लॉगिन क्रेडेंशियल दर्ज करने के लिए कहा जाएगा। हम पहले ही लॉग इन कर चुके हैं, इसलिए हमारा मेल बिना अतिरिक्त चरणों के भेजा जाएगा।

• अंत में, यह स्नैपशॉट मेल मर्ज दिखाता है इरादा के अनुसार काम करता है और यह Excel . का उपयोग करके काम कर सकता है बिना शब्द . के ।

और पढ़ें:एक्सेल से आउटलुक में मेल मर्ज कैसे करें (आसान चरणों के साथ)

आखिरी विधि के लिए, हमने अपने डेटासेट को थोड़ा बदल दिया है। "नाम . से युक्त तीन कॉलम हैं ”, “ईमेल पता ”, और “पाठ " हम एक और VBA . का उपयोग करेंगे मेल मर्ज करने के लिए कोड एक्सेल . में केवल। इस बार, हम इनपुटबॉक्स विधि . का उपयोग करेंगे ईमेल पता और भेजने के लिए पाठ का चयन करने के लिए। इसके अलावा, हम केवल मेल मर्ज प्रदर्शित करेंगे ऑपरेशन आउटलुक एप्लिकेशन और एक बटन पर क्लिक करके इसे मैन्युअल रूप से भेजें। हमारी ईमेल बॉडी सभी ग्राहकों के लिए समान है। आगे की हलचल के बिना, आइए चरणों में कूदें।

चरण:

• सबसे पहले, जैसा कि पहली विधि में दिखाया गया है , मॉड्यूल . लाएं विंडो खोलें और यह कोड टाइप करें।

Public Sub Mail_Merge_Without_Word_Input_Box()
'Declare the variables
    Dim XRcptsEmail As Range
    Dim xMailContent As Range
    Dim xRngDn As Range
    Dim xCrtOut As Object
    Dim xValSendRng As String
    Dim k As Long
    Dim xMailSections As Object
    Dim xFinalRw As Long
    Dim CrVbLf As String
    Dim xMsg As String
    On Error Resume Next
    'Insert a input box for selecting the recipients
    Set XRcptsEmail = Application.InputBox("Choose the column for the email" _
    & "addresses of the recipients:", "ExcelDemy", , , , , , 8)
    If XRcptsEmail Is Nothing Then Exit Sub
    'To enter the text mail, insert a input box
    Set xMailContent = Application.InputBox("In your email," _
    & "choose the column with the text:", "ExcelDemy", , , , , , 8)
    If xMailContent Is Nothing Then Exit Sub
    'Count rows for the recipient email
    xFinalRw = XRcptsEmail.Rows.Count
    Set XRcptsEmail = XRcptsEmail(1)
    Set xMailContent = xMailContent(1)
    'Set command to open MS Outlook Application
    Set xCrtOut = CreateObject("Outlook.Application")
    'Apply For loop to conduct the operation in each row one by one
    For k = 1 To xFinalRw
            xValSendRng = Cells(XRcptsEmail.Offset(k - 1).Row, _
            XRcptsEmail.Offset(k - 1).Column - 1)
            'Create the subject, body and text contents with the required variables
            CrVbLf = "<br><br>"
            xMsg = "<HTML><BODY>"
            xMsg = xMsg & "Dear " & xValSendRng & CrVbLf
            xMsg = xMsg & "" & xMailContent.Value & CrVbLf
            xMsg = xMsg & "</BODY></HTML>"
            'Create the email
            Set xMailSections = xCrtOut.CreateItem(0)
            'Define the position to place the Subject, Body and Recipients Address
            With xMailSections
                .Subject = "Congratulations!!!"
                xValSendRng = Cells(XRcptsEmail.Offset(k - 1).Row, _
                XRcptsEmail.Offset(k - 1).Column)
                .To = xValSendRng
                .HTMLBody = xMsg
                .Display
            End With
            Set xMailSections = Nothing
    Next
    Set xCrtOut = Nothing
End Sub

VBA कोड ब्रेकडाउन

• शुरू करने के लिए, हम उप प्रक्रिया कह रहे हैं Mail_Merge_Without_Word_Input_Box ।
• दूसरा, हम चर प्रकार घोषित कर रहे हैं।
• उसके बाद, हम दो इनपुटबॉक्स . का उपयोग करते हैं ईमेल पते और ईमेल की मुख्य सामग्री प्राप्त करने के लिए।
• फिर, हम पंक्ति संख्या गिनते हैं।
• अगला, हम अगले लूप के लिए का उपयोग करते हैं क्रमिक रूप से सभी पंक्तियों के माध्यम से जाने के लिए और VBA ऑफ़सेट . का उपयोग करके संपत्ति हम 1 . से ग्राहकों के नाम निकालते हैं कॉलम बचा है।
• अंत में, हम प्रदर्शन विधि का उपयोग करते हैं ईमेल का पूर्वावलोकन करने के लिए। वैकल्पिक रूप से, हम भेजने की विधि . का उपयोग कर सकते हैं ईमेल भी भेजने के लिए।

• बाद में, सहेजें मॉड्यूल ।
• फिर, कर्सर को पहले उप प्रक्रिया के अंदर रखें और चलाएं . दबाएं ।

• इसलिए, हमारा कोड निष्पादित होगा और यह हमें ईमेल पते और ईमेल की सामग्री का चयन करने के लिए कहेगा।
• अगला, सेल श्रेणी चुनें C5:C8 ईमेल पते के रूप में और ठीक press दबाएं ।

• बाद में, सेल पर मौजूद ईमेल सामग्री का चयन करें D5 और ठीक press दबाएं ।

• उसके बाद, यह हमें 4 दिखाएगा आउटलुक एप्लिकेशन . की विंडो ।

• अंत में, हम भेजें press दबा सकते हैं इस ईमेल को अग्रेषित करने के लिए।

• यही सफल हुआ मेल मर्ज इसका उपयोग करके आउटपुट VBA कोड जैसा दिखेगा।

और पढ़ें:अनुलग्नकों के साथ Excel से Outlook में मेल मर्ज कैसे करें (2 उदाहरण)

अभ्यास अनुभाग

हमने Excel . में प्रत्येक विधि के लिए एक अभ्यास डेटासेट जोड़ा है फ़ाइल। इसलिए, आप हमारे तरीकों को आसानी से अपना सकते हैं।

निष्कर्ष

हमने आपको दिखाया है 2 VBA मैक्रोज़ मेल मर्ज करने के लिए एक्सेल . में बिना शब्द . यदि आपको इन विधियों के संबंध में कोई समस्या आती है या मेरे लिए कोई प्रतिक्रिया है, तो नीचे टिप्पणी करने में संकोच न करें। इसके अलावा, आप हमारी साइट पर जा सकते हैं ExcelDemy अधिक के लिए एक्सेल-संबंधित लेख। पढ़ने के लिए धन्यवाद, उत्कृष्ट बने रहें!

संबंधित लेख

• एक्सेल से मेल मर्ज दस्तावेज़ को पॉप्युलेट करने के लिए मैक्रो
• एक्सेल मेल मर्ज में दिनांक स्वरूप कैसे बदलें (त्वरित चरणों के साथ)
• एक्सेल फ़ाइल को मेलिंग लेबल में कैसे मर्ज करें (आसान चरणों के साथ)
• एक्सेल से वर्ड लिफाफों में मेल मर्ज करें (2 आसान तरीके)
• एक्सेल से वर्ड में मेल मर्ज पिक्चर्स कैसे करें (2 आसान तरीके)