मुझे Excel स्प्रेडशीट में सूचीबद्ध उपयोगकर्ताओं को ईमेल भेजने का कार्य मिला। प्रत्येक ईमेल में प्रत्येक उपयोगकर्ता के लिए व्यक्तिगत जानकारी होनी थी। मैंने इसे Excel में एक VBA मैक्रो का उपयोग करके करने की कोशिश की जो कंप्यूटर पर कॉन्फ़िगर किए गए Outlook प्रोफाइल से ईमेल भेजता था। यहां मेरा समाधान है।
तैयारी
मान लीजिए, आपके पास निम्न कॉलम वाली एक Excel फ़ाइल है:
Email | Full Name | Last Password Change Date | Account statusमेरा कार्य सूची में प्रत्येक उपयोगकर्ता को इस टेम्पलेट से ऐसा ईमेल भेजना है:
विषय: woshub.com डोमेन पर आपके खाते की स्थिति
बॉडी: प्रिय %FullUsername%,
woshub.com डोमेन में आपका खाता %status% स्थिति में है
अंतिम पासवर्ड परिवर्तन की तारीख और समय %pwdchange% है
मैक्रो बनाना
एक नया मैक्रो बनाएं: View -> Macros. मैक्रो का नाम निर्दिष्ट करें (send_email) और Create पर क्लिक करें।
दिखाई देने वाले VBA संपादक में निम्न कोड कॉपी और पेस्ट करें (मैंने इसमें प्रासंगिक टिप्पणियां जोड़ी हैं)। ईमेल भेजने को स्वचालित करने के लिए, मैं CreateObject ("Outlook.Application") फ़ंक्शन का उपयोग करूंगा जो VBA स्क्रिप्ट के अंदर Outlook ऑब्जेक्ट बनाने और उपयोग करने की अनुमति देता है।
Sub send_email()
Dim olApp As Object
Dim olMailItm As Object
Dim iCounter As Integer
Dim Dest As Variant
Dim SDest As String
' Subject
strSubj = "Your account status on woshub.com domain"
On Error GoTo dbg
' Create a new Outlook object
Set olApp = CreateObject("Outlook.Application")
For iCounter = 1 To WorksheetFunction.CountA(Columns(1))
' Create a new item (email) in Outlook
Set olMailItm = olApp.CreateItem(0)
strBody = ""
useremail = Cells(iCounter, 1).Value
FullUsername = Cells(iCounter, 2).Value
Status = Cells(iCounter, 4).Value
pwdchange = Cells(iCounter, 3).Value
' Make the body of an email
strBody = "Dear " & FullUsername & vbCrLf
strBody = strBody & " Your account in woshub.com domain is in" & Status & " state" & vbCrLf
strBody = strBody & "The date and time of the last password change is" & pwdchange & vbCrLf
olMailItm.To = useremail
olMailItm.Subject = strSubj
olMailItm.BodyFormat = 1
' 1 – text format of an email, 2 - HTML format
olMailItm.Body = strBody
olMailItm.Send
Set olMailItm = Nothing
Next iCounter
Set olApp = Nothing
dbg:
' Display errors, if any
If Err.Description <> "" Then MsgBox Err.Description
End Subइस Excel फ़ाइल को .xlsm (मैक्रो का समर्थन करने वाले Excel वर्कबुक के प्रारूप) के रूप में सहेजें। ईमेल भेजने के लिए, बनाई गई प्रक्रिया (मैक्रो) चुनें और Run पर क्लिक करें।
मैक्रो Excel वर्कशीट पर सभी पंक्तियों को एक-एक करके जाएगा, सूची में प्रत्येक प्राप्तकर्ता के लिए ईमेल उत्पन्न करेगा और भेजेगा।
