Excel शक्तिशाली, बिल्ट-इन सुविधाएँ प्रदान करता है जो आपको डायनामिक और इंटरैक्टिव फ़ाइलें बनाने की अनुमति देती हैं—जैसे रिपोर्ट, डैशबोर्ड, और फॉर्म—बिना किसी VBA के उपयोग के। आप इंटरैक्टिव रिपोर्ट बना सकते हैं जो डेटा को तुरंत अपडेट करती हैं।
इस ट्यूटोरियल में, हम आपको दिखाएंगे कि बिना किसी VBA के इन इंटरैक्टिव फ़ाइलों को कैसे बनाया जाए।
1. अपना डेटासेट तैयार करें
इंटरैक्टिव Excel फ़ाइल बनाने के लिए, आपको अपना डेटासेट साफ और संरचित करना होगा। एक अच्छी तरह से फ़ॉर्मेट और संरचित डेटासेट प्रभावी इंटरैक्टिव व्यवहार बनाने के लिए महत्वपूर्ण है।
- अपना डेटासेट साफ करें।
- डुप्लिकेट और स्पेस हटाएं।
- फ़ॉर्मेटिंग और डेटा प्रकार के मुद्दों को सही करें।
डेटा को टेबल में बदलें
- डेटासेट चुनें।
- Insert टैब पर जाएं >> Table चुनें।
- My table has headers चेक करें।
- OK पर क्लिक करें।
- टेबल का नाम बदलें:
- Table Design टैब पर जाएं >> Table Name चुनें और इसे एक प्रासंगिक नाम दें, जैसे Sales।
2. डेटा सत्यापन ड्रॉप-डाउन सूचियों का उपयोग करें
ड्रॉप-डाउन सूचियाँ इंटरैक्टिव Excel फ़ाइलें बनाने के लिए आवश्यक तत्व हैं। एक ड्रॉप-डाउन सूची त्वरित, सुसंगत, और नियंत्रित उपयोगकर्ता इनपुट सक्षम करती है। बाद में, आप इसका उपयोग डेटा, चार्ट, और KPI को इंटरैक्टिव रूप से फ़िल्टर करने के लिए कर सकते हैं।
चरण:
हेल्पर सूचियाँ बनाएं: अपनी शीट के ऊपर या दाईं ओर हेल्पर सूचियाँ बनाएं। आप इन्हें बाद में छिपा सकते हैं।
- एक सेल चुनें और अद्वितीय क्षेत्रों को सूचीबद्ध करने के लिए निम्न सूत्र दर्ज करें:
=SORT(UNIQUE(Sales[Region]))
- एक सेल चुनें और उत्पाद नामों को सूचीबद्ध करने के लिए निम्न सूत्र दर्ज करें:
=SORT(UNIQUE(Sales[Product]))
- वैकल्पिक: प्रत्येक सूची के ऊपर "All" जोड़ें, फिर अद्वितीय सूची को स्पिल करने के लिए सूत्र डालें।
ड्रॉप-डाउन सूची बनाएं:
- वह सेल चुनें जहां आप ड्रॉप-डाउन चाहते हैं (जैसे, B2)।
- Data टैब पर जाएं >> Data Validation चुनें।
- Allow के तहत, List चुनें।
- Source में, हेल्पर कॉलम से क्षेत्र सूची चुनें।
- OK पर क्लिक करें।
- इसी तरह के चरणों का पालन करके Product के लिए एक ड्रॉप-डाउन सूची बनाएं।
- Allow के तहत, List चुनें।
- Source में, हेल्पर कॉलम से उत्पाद सूची चुनें।
टिप: आप सूचियों के लिए एक नामित रेंज बना सकते हैं और फिर इसे डेटा सत्यापन में उपयोग कर सकते हैं।
3. ड्रॉप-डाउन के साथ डायनामिक सूत्रों का उपयोग करें
ड्रॉप-डाउन के साथ डायनामिक सूत्रों को एकीकृत करने से KPI स्वचालित रूप से अपडेट होते हैं और डेटा फ़िल्टर होता है।
KPI बनाएं:
- कुल राजस्व:
=SUMIFS( Sales[Revenue], Sales[Region], IF($B$2="All","*", $B$2), Sales[Product], IF($B$4="All","*", $B$4))
- औसत छूट:
=AVERAGEIFS( Sales[Discount], Sales[Region], IF($B$2="All","*", $B$2), Sales[Product], IF($B$4="All","*", $B$4))
साफ दिखने के लिए प्रतिशत प्रारूप लागू करें।
- कुल ऑर्डर:
=COUNTIFS( Sales[Region], IF($B$2="All","*", $B$2), Sales[Product], IF($B$4="All","*", $B$4))
- कुल बिकी इकाइयाँ:
=SUMIFS( Sales[Units], Sales[Region], IF($B$2="All","*", $B$2), Sales[Product], IF($B$4="All","*", $B$4))
इंटरएक्टिविटी टेस्ट करें:
- ड्रॉप-डाउन सूचियों से एक क्षेत्र और उत्पाद चुनें।
- KPI स्वचालित रूप से अपडेट होते हैं।
4. नामित रेंज के साथ डायनामिक चार्ट बनाएं
चार्ट बनाएं जो उपयोगकर्ता चयन के आधार पर स्वचालित रूप से अपडेट हों।
फ़िल्टर्ड डेटा:
=FILTER( CHOOSE({1,2}, Sales[Date], Sales[Revenue]), IF($B$2="All", Sales[Region]<>"", Sales[Region]=$B$2) * IF($B$4="All", Sales[Product]<>"", Sales[Product]=$B$4), "No rows")
एक डायनामिक नामित रेंज परिभाषित करें:
- Formulas टैब पर जाएं >> Name Manager चुनें >> New चुनें।
- Name: FilteredDates
- Refers to:
=INDEX('Interactive Sheet'!$B$7#, ,1)
- Name: FilteredRevenue
- Refers to:
=INDEX('Interactive Sheet'!$B$7#, ,2)
चार्ट बनाएं:
- Insert टैब पर जाएं >> Charts से >> Line Chart चुनें।
- चार्ट पर राइट-क्लिक करें >> Select Data चुनें।
- Series Values के लिए, टाइप करें:
='Interactive Sheet'!FilteredRevenue
- Horizontal Axis Labels के लिए:
='Interactive Sheet'!FilteredDates
इंटरएक्टिविटी टेस्ट करें:
- East क्षेत्र और सभी उत्पाद चुनें।
- चार्ट सभी प्रासंगिक डेटा दिखाता है।
- एक विशिष्ट क्षेत्र और एक विशिष्ट उत्पाद चुनें।
- चार्ट तुरंत फ़िल्टर हो जाता है।
- यह किसी भी संयोजन के लिए बिना VBA के काम करता है।
5. दृश्य प्रतिक्रिया के लिए सशर्त स्वरूपण का उपयोग करें
मुख्य मानों या उपयोगकर्ता विकल्पों को तुरंत हाइलाइट करें सशर्त स्वरूपण के साथ।
चरण:
- अपनी डेटा रेंज चुनें।
- Home टैब पर जाएं >> Conditional Formatting चुनें >> New Rule चुनें।
- Use a formula to determine which cells to format चुनें।
- निम्न सूत्र डालें:
=AND(OR('Interactive Sheet'!$B$2="All", $C2='Interactive Sheet'!$B$2), OR('Interactive Sheet'!$B$4="All", $F2='Interactive Sheet'!$B$4))
- एक हाइलाइट रंग चुनें।
- OK पर क्लिक करें।
केवल मिलान वाली पंक्तियाँ हाइलाइट होती हैं, जो फ़िल्टर चयन को दृढ़ता से मजबूत करती हैं।
6. PivotTables, स्लाइसर, और इंटरैक्टिव चार्ट
PivotTables, PivotCharts, और स्लाइसर Excel में मुख्य इंटरैक्टिव विशेषताएं हैं जो डेटा फ़िल्टरिंग को अविश्वसनीय रूप से आसान बनाती हैं।
PivotTable बनाएं:
- अपनी डेटा रेंज चुनें।
- Insert टैब पर जाएं >> PivotTable चुनें।
- स्थान चुनें: New या Existing Worksheet।
- OK पर क्लिक करें।
- PivotTable Fields से:
- Product को Rows क्षेत्र में खींचें।
- Revenue को Values क्षेत्र में खींचें।
PivotCharts बनाएं:
- PivotTable चुनें।
- PivotTable Analyze टैब पर जाएं >> PivotChart चुनें।
- Clustered Column चार्ट चुनें।
- OK पर क्लिक करें।
इंटरैक्टिव स्लाइसर जोड़ें:
- PivotTable Analyze टैब पर जाएं >> Insert Slicer चुनें।
- फ़िल्टर करने के लिए एक फ़ील्ड चुनें, जैसे:
- Region, Product, Salesperson, आदि।
- आप स्लाइसर में बटन पर क्लिक करके चार्ट और टेबल को तुरंत फ़िल्टर कर सकते हैं।
- स्लाइसर और चार्ट को एक साथ रखने के लिए, आप उन्हें ग्रुप कर सकते हैं।
- स्लाइसर को चार्ट पर या उसके पास रखें, सभी ऑब्जेक्ट्स (चार्ट और स्लाइसर) चुनें, फिर राइट-क्लिक करें और Group चुनें।
साझा स्लाइसर के साथ एकाधिक PivotTables कनेक्ट करें
- एक ही डेटा स्रोत से एकाधिक पिवट टेबल बनाएं।
- स्लाइसर डालें।
- स्लाइसर पर राइट-क्लिक करें >> Report Connections चुनें।
- स्लाइसर को एकाधिक PivotTables से कनेक्ट करें।
- अब, स्लाइसर और चार्ट को अपनी डैशबोर्ड शीट पर कॉपी करें।
- आप PivotTable शीट को छिपा सकते हैं।
7. नेविगेशन के लिए हाइपरलिंक का उपयोग करें
अपनी Excel फ़ाइल को क्लिक करने योग्य ऐप जैसा महसूस कराने के लिए, आप नेविगेशन के लिए हाइपरलिंक का उपयोग कर सकते हैं। यह उपयोगकर्ताओं को विभिन्न शीट्स, चार्ट, या टेबल पर जाने की अनुमति देता है।
चरण:
- Insert टैब पर जाएं >> Illustrations से >> Shapes चुनें >> Rectangle चुनें।
- आकार का नाम "Sales Data" रखें।
- आकार पर राइट-क्लिक करें >> Link चुनें।
- Insert Hyperlink डायलॉग बॉक्स में:
- Place in This Document चुनें >> सेल संदर्भ A1 टाइप करें >> Sales शीट चुनें।
- OK पर क्लिक करें।
- Place in This Document चुनें >> सेल संदर्भ A3 टाइप करें >> PivotTable शीट चुनें।
- OK पर क्लिक करें।
- इसे बटन की तरह फ़ॉर्मेट करें एक साफ लुक के लिए।
- इस तरह के नेविगेशन हाइपरलिंक उपयोगकर्ताओं को "डैशबोर्ड" और विभिन्न "विवरण" शीट्स के बीच आसानी से कूदने की अनुमति देते हैं।
अंतिम इंटरैक्टिव Excel फ़ाइल:
- नीचे दिए गए उदाहरण में सभी क्षेत्र और "Accessory" उत्पाद चुना गया है।
- चयन स्लाइसर से भी किए जा सकते हैं।
- सभी डेटा स्वचालित रूप से अपडेट होता है।
टिप्स
- हमने एक डायनामिक चार्ट (FILTER फ़ंक्शन का उपयोग करके) और एक PivotChart दोनों का प्रदर्शन किया ताकि विभिन्न इंटरैक्टिव विधियाँ दिखाई जा सकें। आप जो भी प्रकार आपकी आवश्यकताओं के लिए सबसे उपयुक्त हो, चुन सकते हैं।
- आप Form Controls का भी पता लगा सकते हैं, जो VBA की आवश्यकता के बिना अधिक इंटरैक्टिव विकल्प प्रदान करते हैं।
- सर्च बॉक्स बनाने के लिए, आप डायनामिक XLOOKUP फ़ंक्शन का उपयोग कर सकते हैं।
प्रैक्टिस वर्कबुक डाउनलोड करें
निष्कर्ष
इन सुविधाओं और तकनीकों का उपयोग करके, आप बिना किसी VBA के परिष्कृत, इंटरैक्टिव Excel फ़ाइलें बना सकते हैं। कुंजी अधिकतम इंटरैक्टिविटी के लिए कई तकनीकों को संयोजित करना है। अपने इंटरैक्टिव तत्वों को हमेशा अच्छी तरह से टेस्ट करना याद रखें और उपयोगकर्ताओं के लिए स्पष्ट निर्देश प्रदान करें। अभ्यास के साथ, आप प्रभावशाली डैशबोर्ड और टूल बनाने में सक्षम होंगे जो डेटा विश्लेषण को शक्तिशाली और उपयोगकर्ता-अनुकूल दोनों बनाते हैं, सभी बिना VBA कोड की एक भी लाइन लिखे।
मुफ़्त उन्नत Excel अभ्यास समाधान के साथ प्राप्त करें!
